Gom引擎脚本-行会竞标

GM版本库

;
(@@InPutString @@InPutInteger )
[@main]
<【行会名称】/SCOLOR=58><$STR(A109)>　　
#if
EQUAL A130 开启
#say
<【加入等级】/SCOLOR=58><$STR(G108)>　　←<加入该行会/@加入>\
#elsesay
\
#if
#say
<【竞标时间】/SCOLOR=250><$STR(A110)>\
<【行会掌门】/SCOLOR=253><$STR(A121)>\
<【行会公告】/SCOLOR=254><$STR(A119)>\
━━━━━━━━━━━━━━━━━━━━━━━━━━━━━\
<我可以帮你实现自动收人、离线收人；就算掌门人不在线，您的/SCOLOR=250>\
<行会照样能招收新人，试试吧！/SCOLOR=250>  <注意:每天凌晨0点清空竞标数据!/SCOLOR=58>\
━━━━━━━━━━━━━━━━━━━━━━━━━━━━━\
?【<我要竞标/@我也要竞标>】　　　　　　
#if
isadmin
#say
【<GM管理/@管理>】　　　　　
#elsesay


#if
ISGUILDMASTER
equal A109 <$GUILDNAME>
#say
【<管理选项/@竞标台管理>】
#elsesay
【<管理选项/SCOLOR=58>】

[@test]
#if
checklevelex > 0
#act
SetIcon 3 263
sendmsg 5 55555


[@我也要竞标]
<每个星期一凌晨0点将清除所有竞标信息,原始竞标价格为20元宝!/SCOLOR=254>\
<只要你给出的竞标价格高于对方，你的行会就可以中标!获得竞标/SCOLOR=253>\
<成功的行会给予头顶称号:【天下第一行会】/SCOLOR=250>\
┏━━━━━━━━━━━━━━━━━━━━━━━━━━━┓\
? <【竞标行会】/SCOLOR=250><$STR(A109)>\
　 <【竞标价格】/SCOLOR=250><$STR(G107)><元宝/SCOLOR=58>\
? <【竞标时间】/SCOLOR=250><$STR(A110)>\
┗━━━━━━━━━━━━━━━━━━━━━━━━━━━┛\
【<我要竞标/@竞标开始>】<←只有行会掌门人才可以参与竞标/SCOLOR=58>    【<返回首页/@main>】


[@竞标开始]
#if
ISGUILDMASTER
#act
goto @竞标开始2
#elseact
messagebox 对不起，你不是行会掌门
[@竞标开始2]
#if
equal A109 <$GUILDNAME>
#act
messagebox 错误，你所在的行会已经是中标行会！
break
#elsesay
?\ \ \
→<输入竞标价格/@@InPutInteger70>\ \
→<返回/@main>


[@InPutInteger70]
#if
large n70 <$STR(G107)>
#act
goto @竞标3
#elseact
messagebox 对不起，你的出价太低！

[@竞标3]
#if
CHECKGAMEGOLD < <$STR(n70)>
#act
messagebox 对不起，你没有那么多元宝！
#elsesay
你给出的价格为<$STR(n70)>元宝,请填写完整以下信息：\ \
→<输入招收会员的最低等级要求/@@InPutInteger71>  <(35-100)/SCOLOR=253>\
→<输入一段简短公告/@@InPutString11> <(在雕像上显示)/SCOLOR=253>\
?<[公告]/SCOLOR=250><$STR(s11)>\ \

→<提交信息/@竞标4>

[@InPutInteger71]
#if
large n71 35
small n71 100
#act
messagebox 设定成功，加入你的行会的最低等级要求是<$STR(n71)>级！
#elseact
messagebox 请输入一个35－100间的整数！
goto @竞标3

[@CallInPutString11]
#act
goto @竞标3

[@竞标4]
#If
small n71 35
#act
messagebox 请设定招收会员的最低等级要求！
goto @竞标3
#elsesay
<以下是你的全部信息，点击确定提交信息：/SCOLOR=253>\
<行会名称：/SCOLOR=250><$GUILDNAME>\
<行会掌门：/SCOLOR=250><$USERNAME>\
<竞标价格：/SCOLOR=250><$STR(N70)>元宝\
<竞标时间：/SCOLOR=250><$DATETIME>\
<加入等级：/SCOLOR=250><$STR(N71)>级\
<公告内容：/SCOLOR=250><$STR(S11)>\ \
【<确定提交信息/@竞标5>】              【<返回重新填写/@竞标开始>】


[@竞标5]
#if
CHECKGAMEGOLD > <$STR(n70)>
large n70 <$STR(G107)>
#act
GAMEGOLD - <$STR(n70)>
mov a109 <$GUILDNAME>
mov g107 <$STR(n70)>
mov a110 <$DATETIME>
mov g108 <$STR(n71)>
mov a119 <$STR(s11)>
mov a121 <$USERNAME>
mov A130 开启
GmExeCute 开始提问 @显示天下第一行会
SENDMSG 0 %s在招兵买马那成功竞标!同时册封此行会为【天下第一行会】
close
#elseact
SENDMSG 7 [超时]
goto @main


[@加入]
#if
equal A109 暂无
#act
SENDMSG 6 [非法操作]
goto @main
break
#if
equal A130 开启
#elseact
messagebox 对不起，本行会暂时不收人
break
#IF
HAVEGUILD
#ACT
MESSAGEBOX [失败]:您已经有行会了。无法申请!\请先退出你当前的行会！
break
#if
CHECKLEVELEX < <$STR(G108)>
#act
messagebox 等级不够！
break
#if
#act
AddGuildMember <$STR(A109)>
messagebox 恭喜你已经成功加入到<$STR(A109)>
goto @main

[@竞标台管理]
#if
ISGUILDMASTER
equal a109 <$GUILDNAME>
#act
goto @竞标台管理2
#elseact
SENDMSG 5 [只有本行会掌门才可以进行管理]
goto @main

[@竞标台管理2]
#if
equal A130 开启
#act
mov S2 <开启/SCOLOR=250>
#elseact
mov S2 <禁止/SCOLOR=58>
#if
#say
?\ \
【<行会收人状态/SCOLOR=254>】<$STR(S2)>  【<更改/@gg1>】\ \
【<修改公告内容/@@InPutString12>】<$STR(A119)>\
【<修改等级要求/@@InPutInteger72>】<$STR(G108)>级\ \
<返回/@main>

[@gg1]
#if
equal A130 开启
#act
mov A130 关闭
messagebox 行会收人状态→关闭
goto @竞标台管理
break
#if
equal A130 关闭
#act
mov A130 开启
messagebox 行会收人状态→开启
goto @竞标台管理
break



[@InPutInteger72]
#if
large n72 34
small n72 101
#act
mov g108 <$STR(n72)>
messagebox 设定成功，加入你的行会的最低等级要求是<$STR(n72)>级！
goto @竞标台管理
#elseact
messagebox 请输入一个35－100间的整数！
goto @竞标台管理

[@InPutString12]
#if
equal s12
#act
messagebox 请输入字符..
#elseact
mov a119 <$STR(s12)>
messagebox 修改公告信息成功!!
goto @竞标台管理


[@管理]
#if
isadmin
#say
尊敬的管理员:<$USERNAME> 您好!欢迎使用行会竞标管理系统!\ \ \
　　　　　您目前可用的权限为:<重置竞标数据/@重置>\ \ \
【<返回首页/@main>】
#elseact
messagebox 你不是GM,怎么能看到这个按钮..~~
goto @main

[@重置]
#if
isadmin
#act
messagebox 使用此功能后之前发布的行会信息将清空\请慎重使用此功能,是否开始清理数据! @开始清理 @取消